different panelwidth when aligning with code

Comments

• Eugene Balabuev (LMD)

  June 2020

  Things can get more complicated here. Try to use the following code:

  
  

  function TForm3.GetPanels: TArray<TLMDDockPanel>;

  var

    lst: TList<TLMDDockPanel>;

    i: Integer;

  begin

    lst := TList<TLMDDockPanel>.Create;

    try

      for i := 0 to ComponentCount - 1 do

        if Components[i] is TLMDDockPanel then

          lst.Add(TLMDDockPanel(Components[i]));

      Result := lst.toArray;

    finally

      lst.Free;

    end;

  end;

  
  

  procedure TForm3.ShowPanels(const APanels: TArray<TLMDDockPanel>;

    AShow: Boolean);

  var

    pnl: TLMDDockPanel;

  begin

    for pnl in APanels do

      pnl.PanelVisible := AShow;

  end;

  
  

  procedure TForm3.Button1Click(Sender: TObject);

  var

    i:    Integer;

    pnl:  TLMDDockPanel;

    wd:   Integer;

    pnls: TArray<TLMDDockPanel>;

  begin

    pnls := GetPanels;

    ShowPanels(pnls, False);

  
  

    for pnl in pnls do

      LMDDockSite1.DockControl(pnl, LMDDockSite1.RootZone, alLeft);

  
  

    wd := LMDDockSite1.RootZone.Width div Length(pnls);

    for pnl in pnls do

      pnl.Zone.Width := wd;

  
  

    ShowPanels(pnls, True);

  end;
• Eugene Balabuev (LMD)

  June 2020

  Despite not related to DockingPack itself, I want to mention, that your code:

  
  

  w := Site.RootZone.Width div DocumentCount;
  

  
  

  Is not correct, because not every site width is divisible by panel count. I mean that  w * DocumentCount willl not be equal to Site.RootZone.Width, because of integer division.

  You have to use some floating point arithmetic here (with rounding to integer panel widths). I guess you'll realize it after trying the simpler original way.
  
• IDKOSCH

  June 2020 edited June 2020

  Thank you, your code works with a little problem:

  
  

  If i make the main-window smaller, all panels will be smaller, ok, 

  but if i make the main-window wider, all panels keep their width and don't grow.

  
  

  Stefan
• Eugene Balabuev (LMD)

  June 2020

  Because all of them are now aligned to the left.  You can align one of them to alClient and then this panel will be expanded on window expand.
• Eugene Balabuev (LMD)

  June 2020

  If you want all panels to be expanded uniformly, you have to set Site.UseSpace property to False. Updated code:

  
  

  procedure TForm3.Button1Click(Sender: TObject);

  var

    pnl:  TLMDDockPanel;

    sw:   Integer;

    wd:   Integer;

    pnls: TArray<TLMDDockPanel>;

    szs:  TArray<Integer>;

    i:    Integer;

  begin

    pnls := GetPanels;

    ShowPanels(pnls, False);

  
  

    for pnl in pnls do

      LMDDockSite1.DockControl(pnl, LMDDockSite1.RootZone, alLeft);

  
  

    sw := LMDDockManager1.DockElems.HorzZone.SplitterWidth.Value[dv100];

    wd := (LMDDockSite1.RootZone.Width - sw * High(pnls)) div Length(pnls);

  
  

    SetLength(szs, Length(pnls));

    for i := 0 to High(szs) do

      szs[i] := wd;

  
  

    ShowPanels(pnls, True);

    LMDDockSite1.RootZone.SetChildrenSizes(szs);

  end;
• IDKOSCH

  June 2020 edited June 2020

  Thank you, but this doesn't work!

  
  

  If i make the mainform smaller, all panels get smaller, but if i make the mainform wider, all panels dont grow...

  If i drag panels with mouse and drop them side by side, the panels will be greater or smaller when i change mainform with mouse.

  I would like to set this up exactly by code.

  
  

  Stefan
  
• Eugene Balabuev (LMD)

  June 2020

  I've already mentioned this aspect. IF you want panels to widen you generally have two options:

  
  

  1) The code shows aligning all panels to the left. But, you can align one of them as alClient, so allowing it to widen and fill all remaining area.

  2) You can switch off site's SpaceZone concept setting Site.UseSpace property to False. In this case panels will expand uniformly, but UseSpace is applicable to the whole site.

  
  

  Its generally hard to say, what is your setup. Can you send a demo along with screeenshots (including small and large window sizes) and steps to reproduce of how you achieve what you need with mouse. I just want to look at resulting layout.
• IDKOSCH

  June 2020

  I have changed your code to 

  
  

    for pnl in pnls do

      Site.DockControl(pnl, Site.RootZone, alDocLeft);

  
  

  and now all works fine ;-)

  
  

  Stefan